Array

Jika record bisa menggabungkan beberapa variabel dengan tipe yang berbeda-beda menjadi sebuah variabel. Maka array dapat mengumpulkan banyak variabel yang sejenis menjadi satu variabel. Untuk membuat array, kita bisa melakukan seperti berikut:

var NamaVariabel:array[index1..index2]of tipe;

index1 adalah indek bawah dari array, sedangkan index2 adalah indek atas darai array.

Contoh program yang menggunakan array

program ArrayData;
{$APPTYPE CONSOLE}
var data:array[0..4]of integer;
    index:integer;
begin
  //ambil data
  for index:=0 to 4 do
  begin
    Write('Masukkan sebuah angka: ');
    Readln(data[index]);
  end;
  //tampilkan data
  Writeln(#13#10'Data yang Anda masukkan adalah:');
  for index:=0 to 4 do
    Writeln('Data ke ',index,': ',data[index]);

  Writeln(#13#10'Tekan Enter');
  Readln;
end.

data adalah kumpulan 5 buah variabel dengan tipe integer. Variabel pertama diacu dengan data[0], data kedua diacu dengan data[1] dan seterusnya. Jadi cara mengacu variabel dengan tipe array adalah dengan menyebut nama variabelnya diikuti dengan indek dari elemen datanya di dalam kurung kotak.

Dalam memberikan indek kepada variabel bertipe array, kita harus memastikan bahwa indek yang diberikan berada dalam jangkauan variabel tersebut. Sebagai contoh, kita tidak boleh mengacu data[-1] atau data[5]. Kalau hal tersebut dilakukan maka program akan mengalami kesalahan. Kita dapat mengetahui indek bawah dari sebuah array dengan fungsi low dan mengetahui indek atas dari array dengan fungsi high. Sebagai contoh, untuk mengisi semua elemen dari variabel data, kita bisa melakukan dengan cara:

for index:=low(data) to high(data) do data[index]:=....

Sebuah array dapat berisi array yang lain. Kita juga dapat membuat array menjadi sebuah tipe data. Contoh:

type
  TDataArray=array[0..10]of integer;

var
  //data dari TDataArray
  MyData:TDataArray;
  //array data dari TDataArray
  MyArray:array[0..10]of TDataArray;
  //array yang lain
  MyArray1:array[0..10]of array[0..10]of integer;
  MyArray2:array[0..10,0..10]of integer;

Array yang berisi array disebut dengan array dua dimensi. MyArray adalah array yang berisi array. Jadi MyArray adalah array dua dimensi. MyArray1 maupun MyArray2 memiliki bentuk dan jumlah elemen yang sama dengan MyArray. Anda dapat membuat array banyak dimensi.

Untuk mengacu elemen-elemen di dalam array banyak dimensi, kita memisahkan nomor indeknya dengan koma di dalam kurung kotak, misalnya:

MyArray1[0,0]:=5;

String adalah array karakter

Dari awal kita sudah mengatakan bahwa string adalah untaian (array) dari karakter. Oleh karena itu kita bisa mendapatkan karakter tunggal dari sebuah string dengan memberikan nomor indek elemennya. Karakter pertama dari sebuah string memiliki nomor indek 1.

Untuk mengetahui panjang dari sebuah string dapat dilakukan dengan menggunakan fungsi length.

program ArrayKarakter;
{$APPTYPE CONSOLE}
var S:string;
    i:integer;
begin
  S:='Array';
  for i:=1 to length(S)do Writeln(S[i]);
  Writeln('Tekan Enter');
  Readln;
end.

Jika program tersebut dijalankan, maka tampilannya adalah seperti berikut:

A
r
r
a
y
Tekan Enter

Apakah Anda menyukai post ini? Mengapa tidak memberikan komentar di bawah dan melanjutkan perbincangan, atau berlangganan my feed dan dapatkan artikel semacam ini yang dikirm secara otomatis feed reader Anda.
Harap diperhatikan bahwa komentar atau pertanyaan yang disampaikan haruslah sesuai dengan topik yang sedang dibahas. Komentar atau pertanyaan yang tidak sesuai dengan topik akan kami hapus :!:

Tinggalkan komentar

Sebelum membuat komentar, pastikan Anda telah membaca komentar-komentar sebelumnya. Jangan membuat pertanyaan yang telah ditanyakan. Perhatikan pula link-link dalam artikel. Lihatlah link tersebut sebelum membuat pertanyaan, karena mungkin penjelasan dari pertanyaan Anda telah di jawab dalam link tersebut.

Komentar yang tidak mengikuti aturan ini akan dihapus!

(wajib)

(wajib)


Time limit is exhausted. Please reload the CAPTCHA.